一直都見大部分OMSI香港車款自駕版的車門script都不能套用作AI車上，因導致中門要極長時間關上（司機位中門制不停扭動），所以要特登開多個AI.bus，改用AI門script解決，使用此方法的包括康豪、熱蘭、熱豪、VA、S3N等。雖然奏效，但次次都要咁有點不太方便。同時發覺自駕版在遊戲中轉成AI時會出問題（例如ES龍由自駕變成AI會不停飛站，直接用以上方法整AI.bus會error）。而SF個door script就自駕車同AI都能兼容。所以想一齊在此討論修改door.osc檔案的可能性，令更多OMSI RHD巴士能不需要特登開多個AI.bus情況下作AI巴士用。
其實問題在中門上，因此我想知如何改相關字句。

door.AI.osc來自此教學方法：
p2493678.htm#p2493678

以VA為例：
在door_modern_kacha.osc最底找到：

代碼: 選擇全部

{macro:trg_bus_dooraft}
   (L.L.doorTarget_23) ! (S.L.doorTarget_23)
        {if}
                (T.L.ev_doortriggeropen_2)
        {else}
                (T.L.ev_doortriggerclose_2)
        {endif}       
                (C.L.door_druckluft)
                {if}
                (L.L.bremse_p_Tank04) 100000 - 0.98 * 100000 + (S.L.bremse_p_Tank04)
                {endif}
{end}

而在door_AI.osc最底找到：

代碼: 選擇全部

{macro:trg_bus_dooraft}
   (L.L.bremse_halte_sw) ! (S.L.bremse_halte_sw)
   
   (L.L.bremse_halte_sw)
   {if}
      (T.L.ev_haltebremse_sw_an)
   {else}
      (T.L.ev_haltebremse_sw_aus)
   {endif}   
{end}

我嘗試將AI.bus果段取代door_modern_kacha.osc果段，結果AI成功運作，但自駕版就無法開中門。
之後又望過{macro:Door2_Calc},{macro:Door3_Calc}，找到當中的分別：

door_modern_kacha.osc內：

代碼: 選擇全部

{macro:Door2_Calc}
   (C.L.electric_doors)
   {if}
      (L.L.doorTarget_23)
      {if}
         (L.L.door_2) (F.L.door_2_opn_speed) (S.L.doorMaxSpeed_2)
      {else}
         (L.L.door_2) (F.L.door_2_cls_speed) (S.L.doorMaxSpeed_2)
      {endif}

      (C.L.bdoor_acc) (S.L.doorAcc_2)

      (L.L.doorTarget_23) ! (L.L.doorSpeed_2) s0 abs 0.05 > (L.L.door_2) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_2) <
         {if}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
         {else}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
         {endif}
         (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
      {else}
         (L.L.doorSpeed_2) abs 0.05 > (L.L.door_2) 1 < || (L.L.doorTarget_23) &&
         {if}
            l0 (L.L.doorMaxSpeed_2) <
            {if}
               (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
            {else}
               (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
            {endif}
            (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
         {else}
            0 (S.L.doorSpeed_2)
         {endif}
      {endif}
   {else}
      (L.L.doorTarget_23) ! (L.L.doorSpeed_2) s0 abs 0.05 > (L.L.door_2) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_2) <
         {if}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
         {endif}
         (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
      {else}
         (L.L.doorSpeed_2) abs 0.05 > (L.L.door_2) 1 < || (L.L.doorTarget_23) &&
         {if}
            l0 (L.L.doorMaxSpeed_2) <
            {if}
               (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
            {endif}
            (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
         {else}
            0 (S.L.doorSpeed_2)
         {endif}
      {endif}
   {endif}

   (L.L.door_2) 1 >
   {if}
      (T.L.ev_doorhitopen_2)
      1 (S.L.door_2)
      (L.L.doorSpeed_2) /-/ (L.L.doorRefl_2) * (S.L.doorSpeed_2)
   {else}
      (L.L.door_2) 0 <
      {if}
         (T.L.ev_doorhitclose_2)
         0 (S.L.door_2)
         (L.L.doorSpeed_2) /-/ (L.L.doorRefl_2) * (S.L.doorSpeed_2)
      {endif}
   {endif}
{end}

door_AI.osc內：

代碼: 選擇全部

{macro:Door2_Calc}
   (L.L.doorTarget_23) ! (L.L.doorSpeed_2) s0 abs 0.05 > (L.L.door_2) 0 > || &&
   {if}
      l0 /-/ (L.L.doorMaxSpeed_2) <
      {if}
         (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
      {endif}
      (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
   {else}
      (L.L.doorSpeed_2) abs 0.05 > (L.L.door_2) 1 < || (L.L.doorTarget_23) &&
      {if}
         l0 (L.L.doorMaxSpeed_2) <
         {if}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
         {endif}
         (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
      {else}
         0 (S.L.doorSpeed_2)
      {endif}
   {endif}

   (L.L.door_2) 1 >
   {if}
      (T.L.ev_doorhitopen_2)
      1 (S.L.door_2)
      (L.L.doorSpeed_2) /-/ (L.L.doorRefl_2) * (S.L.doorSpeed_2)
   {else}
      (L.L.door_2) 0 <
      {if}
         (T.L.ev_doorhitclose_2)
         0 (S.L.door_2)
         (L.L.doorSpeed_2) /-/ (L.L.doorRefl_2) * (S.L.doorSpeed_2)
      {endif}
   {endif}
{end}

各自的{macro:Door3_Calc}也很相似，分別只是2改成3。
於是我同樣嘗試將AI果段放入自駕版果段，但令自駕版中門完全無法打開。
自知對script認識很淺，離做整OMSI車開發者仍有一大段距離，所以想向大家請教。

紅色AI代表AI.bus，綠色AI代表自駕車以AI bus模式運作

我覺得樓主用意係好，可惜有啲捉錯用神。

自駕車嘅門script喺AI模式下，中門會關得好慢(準確地說，係不斷開關，所以門掣會不停扭動)，表示"doorTarget_23"呢個variable不停被0、1、0、1、0...咁set法--"doorTarget_23"嘅用處，就係話畀{macro:Door2_Calc}同{macro:Door3_Calc}呢兩個macro知，到底中門係要開定係要關。所以當"doorTarget_23"不斷遊走於0同1之間，中門就會不斷開關。

即係話，{macro:Door2_Calc}同{macro:Door3_Calc}入面嘅嘢，唔係中門不斷開關嘅基本原因，問題嘅根源在於設定"doorTarget_23"嘅數值嘅script。而由於問題只會喺AI模式下出現，出問題嘅script入面一定有同AI有關嘅variable，所以範圍就收窄到同"AI"&"doorTarget_23"有關嘅script。

閞door_modern_kacha.osc，搵"L.L.AI"就會搵到

代碼: 選擇全部

'----------------------
'   AI-Ablauf:

(L.L.AI_Scheduled_AtStation) s0
1 =
{if}
'Wenn Türen geöffnet werden sollen:
   (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) <
   {if}
'Nur, wenn v < maxkmh, sonst warten
'Taster jeweils nur betätigen, falls noch nicht an
      (L.L.bremse_halte_sw) !
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) ! (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_doorfront0)
      {endif}
      (L.L.doorTarget_1) ! (L.L.door_AI_timer) 0.6 > &&
      {if}
         (M.L.trg_bus_doorfront1)
      {endif}
   {else}
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{else}
l0 -1 =
{if}
'Wenn Türen geschlossen werden sollen:
'Taster jeweils nur betätigen, falls noch nicht aus:
   (L.L.doorTarget_1)
   {if}
      (M.L.trg_bus_doorfront1)
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.doorTarget_0) (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_doorfront0)
   {endif}
'Haltestellenbremse erst wegnehmen, wenn alle Türen zu. Dann auch erst den Bus AI-mäßig freigeben:
   (L.L.door_0) 0.1 <
   (L.L.door_1) 0.1 < &&
   (L.L.door_2) 0.1 < &&
   {if}
      (L.L.bremse_halte_sw) (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.bremse_halte_sw) !
      {if}
         0 (S.L.AI_Scheduled_AtStation)
      {endif}
   {else}
'Sollte eine der Türen auf sein und die Haltestellenbremse aus, dann sofort diese einlegen
      (L.L.bremse_halte_sw) !
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) !
      (L.L.doorTarget_1) ! &&
      {if}
         0 (S.L.door_AI_timer)
      {endif}
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{endif}
{endif}

而問題就係出喺度。

先解釋一吓：當AI埋緊站，AI_Scheduled_AtStation就係1，準備出站就係-1，行緊就係0。所以要解決中門關門嘅問題，就係睇"l0 -1 ="之後嗰段。

可以見到當中門位置(L.L.door_2)<0.1，就會run

代碼: 選擇全部

      (L.L.bremse_halte_sw) !
      {if}
         (M.L.trg_bus_dooraft)
      {endif}

(M.L.trg_bus_dooraft)即係run{macro:trg_bus_dooraft}，而樓主已經quote咗{macro:trg_bus_dooraft}入面嘅script。
{macro:trg_bus_dooraft}入面有

代碼: 選擇全部

(L.L.doorTarget_23) ! (S.L.doorTarget_23)

即係如果"doorTarget_23"係0就set佢做1，如果佢係1就set佢做0。由於"bremse_halte_sw"(即係原裝車嘅door lock)永遠係0(自駕車版VA已廢除door lock)，所以就會不斷run{macro:trg_bus_dooraft}，即係不斷將"doorTarget_23"0、1、0、1、0...咁set。

所以好明顯，要解決呢個中門不斷開關嘅問題，就要改run{macro:trg_bus_dooraft}嘅condition。
改咗之後：

代碼: 選擇全部

'----------------------
'   AI-Ablauf:

(L.L.AI_Scheduled_AtStation) s0
1 =
{if}
'Wenn Türen geöffnet werden sollen:
   (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) <
   {if}
'Nur, wenn v < maxkmh, sonst warten
'Taster jeweils nur betätigen, falls noch nicht an
      (L.L.doorTarget_23) ! (L.L.haltewunsch) &&
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) ! (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_doorfront0)
      {endif}
      (L.L.doorTarget_1) ! (L.L.door_AI_timer) 0.6 > &&
      {if}
         (M.L.trg_bus_doorfront1)
      {endif}
   {else}
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{else}
l0 -1 =
{if}
'Wenn Türen geschlossen werden sollen:
'Taster jeweils nur betätigen, falls noch nicht aus:
   (L.L.doorTarget_1)
   {if}
      (M.L.trg_bus_doorfront1)
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.doorTarget_0) (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_doorfront0)
   {endif}
'Haltestellenbremse erst wegnehmen, wenn alle Türen zu. Dann auch erst den Bus AI-mäßig freigeben:
   (L.L.door_0) 0.1 <
   (L.L.door_1) 0.1 < &&
   (L.L.door_2) 0.1 < &&
   {if}
      0 (S.L.AI_Scheduled_AtStation)
   {else}
'Sollte eine der Türen auf sein und die Haltestellenbremse aus, dann sofort diese einlegen
      (L.L.doorTarget_23)
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) !
      (L.L.doorTarget_1) ! &&
      {if}
         0 (S.L.door_AI_timer)
      {endif}
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{endif}
{endif}

只係改咗三樣嘢：
1.將埋站時run{macro:trg_bus_dooraft}嘅condition由「door lock未開」改為「中門未開」&「有人打鐘」
2.將準備出站時run{macro:trg_bus_dooraft}嘅condition改成doorTarget_23嘅數值(即係如果中門仲係喺「開」模式就run{macro:trg_bus_dooraft}，轉做「關」模式，之後就唔再重複)
3.將原本要關好門同埋door lock off先可以出站，改為關好門就可以出站
即係將車門開關同door lock完全獨立。

改完之後，無論係自駕車、自駕車轉AI定係AI巴，都可以用同一段script正常運作

希望大家睇得明

謝謝FF兄!同時發現ES龍同大口蘭已能作AI使用。作為車輛script初哥，實在需要繼續學習。

見樓主有興趣研究

E400 既 door_modern.osc 都係同 AI 共用既
歡迎參考一下

改 AI 個部份同 FF 兄既 logic 類近
但係寫法就唔同
唔係由改 macro 入手

請恕我冇時間擺 code 上黎一齊討論

FF3170 on 2014年3月18日 18:11:34: 我覺得樓主用意係好，可惜有啲捉錯用神。

自駕車嘅門script喺AI模式下，中門會關得好慢(準確地說，係不斷開關，所以門掣會不停扭動)，表示"doorTarget_23"呢個variable不停被0、1、0、1、0...咁set法--"doorTarget_23"嘅用處，就係話畀{macro:Door2_Calc}同{macro:Door3_Calc}呢兩個macro知，到底中門係要開定係要關。所以當"doorTarget_23"不斷遊走於0同1之間，中門就會不斷開關。

即係話，{macro:Door2_Calc}同{macro:Door3_Calc}入面嘅嘢，唔係中門不斷開關嘅基本原因，問題嘅根源在於設定"doorTarget_23"嘅數值嘅script。而由於問題只會喺AI模式下出現，出問題嘅script入面一定有同AI有關嘅variable，所以範圍就收窄到同"AI"&"doorTarget_23"有關嘅script。

閞door_modern_kacha.osc，搵"L.L.AI"就會搵到

代碼: 選擇全部

'----------------------
'   AI-Ablauf:

(L.L.AI_Scheduled_AtStation) s0
1 =
{if}
'Wenn Türen geöffnet werden sollen:
   (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) <
   {if}
'Nur, wenn v < maxkmh, sonst warten
'Taster jeweils nur betätigen, falls noch nicht an
      (L.L.bremse_halte_sw) !
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) ! (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_doorfront0)
      {endif}
      (L.L.doorTarget_1) ! (L.L.door_AI_timer) 0.6 > &&
      {if}
         (M.L.trg_bus_doorfront1)
      {endif}
   {else}
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{else}
l0 -1 =
{if}
'Wenn Türen geschlossen werden sollen:
'Taster jeweils nur betätigen, falls noch nicht aus:
   (L.L.doorTarget_1)
   {if}
      (M.L.trg_bus_doorfront1)
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.doorTarget_0) (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_doorfront0)
   {endif}
'Haltestellenbremse erst wegnehmen, wenn alle Türen zu. Dann auch erst den Bus AI-mäßig freigeben:
   (L.L.door_0) 0.1 <
   (L.L.door_1) 0.1 < &&
   (L.L.door_2) 0.1 < &&
   {if}
      (L.L.bremse_halte_sw) (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.bremse_halte_sw) !
      {if}
         0 (S.L.AI_Scheduled_AtStation)
      {endif}
   {else}
'Sollte eine der Türen auf sein und die Haltestellenbremse aus, dann sofort diese einlegen
      (L.L.bremse_halte_sw) !
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) !
      (L.L.doorTarget_1) ! &&
      {if}
         0 (S.L.door_AI_timer)
      {endif}
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{endif}
{endif}

而問題就係出喺度。

先解釋一吓：當AI埋緊站，AI_Scheduled_AtStation就係1，準備出站就係-1，行緊就係0。所以要解決中門關門嘅問題，就係睇"l0 -1 ="之後嗰段。

可以見到當中門位置(L.L.door_2)

唔係

<0.1，就會run

代碼: 選擇全部

      (L.L.bremse_halte_sw) !
      {if}
         (M.L.trg_bus_dooraft)
      {endif}

(M.L.trg_bus_dooraft)即係run{macro:trg_bus_dooraft}，而樓主已經quote咗{macro:trg_bus_dooraft}入面嘅script。
{macro:trg_bus_dooraft}入面有

代碼: 選擇全部

(L.L.doorTarget_23) ! (S.L.doorTarget_23)

即係如果"doorTarget_23"係0就set佢做1，如果佢係1就set佢做0。由於"bremse_halte_sw"(即係原裝車嘅door lock)永遠係0(自駕車版VA已廢除door lock)，所以就會不斷run{macro:trg_bus_dooraft}，即係不斷將"doorTarget_23"0、1、0、1、0...咁set。

所以好明顯，要解決呢個中門不斷開關嘅問題，就要改run{macro:trg_bus_dooraft}嘅condition。
改咗之後：

代碼: 選擇全部

'----------------------
'   AI-Ablauf:

(L.L.AI_Scheduled_AtStation) s0
1 =
{if}
'Wenn Türen geöffnet werden sollen:
   (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) <
   {if}
'Nur, wenn v < maxkmh, sonst warten
'Taster jeweils nur betätigen, falls noch nicht an
      (L.L.doorTarget_23) ! (L.L.haltewunsch) &&
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) ! (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_doorfront0)
      {endif}
      (L.L.doorTarget_1) ! (L.L.door_AI_timer) 0.6 > &&
      {if}
         (M.L.trg_bus_doorfront1)
      {endif}
   {else}
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{else}
l0 -1 =
{if}
'Wenn Türen geschlossen werden sollen:
'Taster jeweils nur betätigen, falls noch nicht aus:
   (L.L.doorTarget_1)
   {if}
      (M.L.trg_bus_doorfront1)
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.doorTarget_0) (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_doorfront0)
   {endif}
'Haltestellenbremse erst wegnehmen, wenn alle Türen zu. Dann auch erst den Bus AI-mäßig freigeben:
   (L.L.door_0) 0.1 <
   (L.L.door_1) 0.1 < &&
   (L.L.door_2) 0.1 < &&
   {if}
      0 (S.L.AI_Scheduled_AtStation)
   {else}
'Sollte eine der Türen auf sein und die Haltestellenbremse aus, dann sofort diese einlegen
      (L.L.doorTarget_23)
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) !
      (L.L.doorTarget_1) ! &&
      {if}
         0 (S.L.door_AI_timer)
      {endif}
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{endif}
{endif}

只係改咗三樣嘢：
1.將埋站時run{macro:trg_bus_dooraft}嘅condition由「door lock未開」改為「中門未開」&「有人打鐘」
2.將準備出站時run{macro:trg_bus_dooraft}嘅condition改成doorTarget_23嘅數值(即係如果中門仲係喺「開」模式就run{macro:trg_bus_dooraft}，轉做「關」模式，之後就唔再重複)
3.將原本要關好門同埋door lock off先可以出站，改為關好門就可以出站
即係將車門開關同door lock完全獨立。

改完之後，無論係自駕車、自駕車轉AI定係AI巴，都可以用同一段script正常運作

希望大家睇得明

不過我將你呢段野抄落去CTB397同344，load city時就彈error，話door ai timer xxxxxx,跟著就入不到game。請問是否不是抄呢篇文的code呢？Thanks!

ap136 on 2014年3月23日 19:09:48:

FF3170 on 2014年3月18日 18:11:34: 所以好明顯，要解決呢個中門不斷開關嘅問題，就要改run{macro:trg_bus_dooraft}嘅condition。
改咗之後：

代碼: 選擇全部

'----------------------
'   AI-Ablauf:

(L.L.AI_Scheduled_AtStation) s0
1 =
{if}
'Wenn Türen geöffnet werden sollen:
   (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) <
   {if}
'Nur, wenn v < maxkmh, sonst warten
'Taster jeweils nur betätigen, falls noch nicht an
      (L.L.doorTarget_23) ! (L.L.haltewunsch) &&
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) ! (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_doorfront0)
      {endif}
      (L.L.doorTarget_1) ! (L.L.door_AI_timer) 0.6 > &&
      {if}
         (M.L.trg_bus_doorfront1)
      {endif}
   {else}
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{else}
l0 -1 =
{if}
'Wenn Türen geschlossen werden sollen:
'Taster jeweils nur betätigen, falls noch nicht aus:
   (L.L.doorTarget_1)
   {if}
      (M.L.trg_bus_doorfront1)
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.doorTarget_0) (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_doorfront0)
   {endif}
'Haltestellenbremse erst wegnehmen, wenn alle Türen zu. Dann auch erst den Bus AI-mäßig freigeben:
   (L.L.door_0) 0.1 <
   (L.L.door_1) 0.1 < &&
   (L.L.door_2) 0.1 < &&
   {if}
      0 (S.L.AI_Scheduled_AtStation)
   {else}
'Sollte eine der Türen auf sein und die Haltestellenbremse aus, dann sofort diese einlegen
      (L.L.doorTarget_23)
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) !
      (L.L.doorTarget_1) ! &&
      {if}
         0 (S.L.door_AI_timer)
      {endif}
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{endif}
{endif}

只係改咗三樣嘢：
1.將埋站時run{macro:trg_bus_dooraft}嘅condition由「door lock未開」改為「中門未開」&「有人打鐘」
2.將準備出站時run{macro:trg_bus_dooraft}嘅condition改成doorTarget_23嘅數值(即係如果中門仲係喺「開」模式就run{macro:trg_bus_dooraft}，轉做「關」模式，之後就唔再重複)
3.將原本要關好門同埋door lock off先可以出站，改為關好門就可以出站
即係將車門開關同door lock完全獨立。

改完之後，無論係自駕車、自駕車轉AI定係AI巴，都可以用同一段script正常運作

希望大家睇得明

不過我將你呢段野抄落去CTB397同344，load city時就彈error，話door ai timer xxxxxx,跟著就入不到game。請問是否不是抄呢篇文的code呢？Thanks!

我自己喺VA、2XX、3XX同4XX度試過，都係冇問題(抄同一段code)，會唔會係你之前有改過/裝過同門script有關嘅addon？
可唔可以貼埋個logfile.txt上嚟？

FF3170 on 2014年3月24日 10:27:12:

ap136 on 2014年3月23日 19:09:48:

FF3170 on 2014年3月18日 18:11:34: 所以好明顯，要解決呢個中門不斷開關嘅問題，就要改run{macro:trg_bus_dooraft}嘅condition。
改咗之後：

代碼: 選擇全部

'----------------------
'   AI-Ablauf:

(L.L.AI_Scheduled_AtStation) s0
1 =
{if}
'Wenn Türen geöffnet werden sollen:
   (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) <
   {if}
'Nur, wenn v < maxkmh, sonst warten
'Taster jeweils nur betätigen, falls noch nicht an
      (L.L.doorTarget_23) ! (L.L.haltewunsch) &&
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) ! (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_doorfront0)
      {endif}
      (L.L.doorTarget_1) ! (L.L.door_AI_timer) 0.6 > &&
      {if}
         (M.L.trg_bus_doorfront1)
      {endif}
   {else}
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{else}
l0 -1 =
{if}
'Wenn Türen geschlossen werden sollen:
'Taster jeweils nur betätigen, falls noch nicht aus:
   (L.L.doorTarget_1)
   {if}
      (M.L.trg_bus_doorfront1)
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.doorTarget_0) (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_doorfront0)
   {endif}
'Haltestellenbremse erst wegnehmen, wenn alle Türen zu. Dann auch erst den Bus AI-mäßig freigeben:
   (L.L.door_0) 0.1 <
   (L.L.door_1) 0.1 < &&
   (L.L.door_2) 0.1 < &&
   {if}
      0 (S.L.AI_Scheduled_AtStation)
   {else}
'Sollte eine der Türen auf sein und die Haltestellenbremse aus, dann sofort diese einlegen
      (L.L.doorTarget_23)
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) !
      (L.L.doorTarget_1) ! &&
      {if}
         0 (S.L.door_AI_timer)
      {endif}
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{endif}
{endif}

只係改咗三樣嘢：
1.將埋站時run{macro:trg_bus_dooraft}嘅condition由「door lock未開」改為「中門未開」&「有人打鐘」
2.將準備出站時run{macro:trg_bus_dooraft}嘅condition改成doorTarget_23嘅數值(即係如果中門仲係喺「開」模式就run{macro:trg_bus_dooraft}，轉做「關」模式，之後就唔再重複)
3.將原本要關好門同埋door lock off先可以出站，改為關好門就可以出站
即係將車門開關同door lock完全獨立。

改完之後，無論係自駕車、自駕車轉AI定係AI巴，都可以用同一段script正常運作

希望大家睇得明

不過我將你呢段野抄落去CTB397同344，load city時就彈error，話door ai timer xxxxxx,跟著就入不到game。請問是否不是抄呢篇文的code呢？Thanks!

我自己喺VA、2XX、3XX同4XX度試過，都係冇問題(抄同一段code)，會唔會係你之前有改過/裝過同門script有關嘅addon？
可唔可以貼埋個logfile.txt上嚟？

請問是改door_modern_kacha.osc 嗎？如果是的，我將你段code replace左原本個段之後，之前並無改任何關於door的野，入game時就出ai door timer 呢個error，跟著就入不到了
本人的code如下：

代碼: 選擇全部

'##############
'Door Script
'##############

'Controls Doors

'(c) 2007-2009 Rüdiger Hülsmann
'(c) 2007-2009 Marcel Kuhnt

'Script Version: 1.1
'Omsi release: 1.0

'Needs:
'- elec

'Revision History:
'- Marcel Kuhnt      13.06.2009   Batterietrennschalter => elec_busbar_main
'- Marcel Kuhnt      21.06.2009   AI-Unterstützung hinzugefügt   
'- Rüdiger Hülsmann   24.10.2009   Ansteuerung des Kinderwagenwunsches modifiziert
'- Rüdiger Hülsmann   19.12.2009   Timer für Ausstiegstür jetzt Timegap-basiert, Bugfix: Tür schließt jetzt nur bei elec_busbar=1
'- RÜdiger Hülsmann   22.09.2010   Door light trigger value set to 0.1
'- RÜdiger Hülsmann   07.11.2010   Door speed based on reservoir pressure, air-operated doors made an option
'- Marcel Kuhnt      08.11.2010   AI procedure closing doors debugged
'- Rüdiger Hülsmann   21.11.2010   Front doors only operable when busbar on
'- Rüdiger Hülsmann   23.12.2010   External front door operation included, option: doors only operable with actual stop brake
'- Rüdiger Hülsmann   31.12.2010   Electric door function debugged
'- Rüdiger Hülsmann   05.01.2011   20h-switch
'- Rüdiger Hülsmann   07.01.2011   Backdoor manual switch sound debugged, 20h switch depending on bus type
'- Rüdiger Hülsmann   19.01.2011   Electric door support
'- "KACHA" ADDED   26-04-2012   "KACHA" WHEN ALL DOORS CLOSED

'--------------------------------------------------------------------------------

{trigger:bus_doorfront0}
   (L.L.doorTarget_0) !
   {if}
      (M.L.trg_bus_doorfront0)
      1 (S.L.cockpit_tuertaster1)
   {else}
      (M.L.trg_front_door_all_close)
   {endif}
{end}

{trigger:bus_doorfront0_off}
   0 (S.L.cockpit_tuertaster1) (S.L.cockpit_tuertaster3)
{end}

{trigger:bus_doorfront1}
   (L.L.doorTarget_0) !
   (L.L.doorTarget_1) ! ||
   {if}
      (M.L.trg_bus_doorfront1)
      1 (S.L.cockpit_tuertaster2)
   {else}
      (M.L.trg_front_door_all_close)
   {endif}
{end}

{trigger:bus_doorfront1_off}
   0 (S.L.cockpit_tuertaster2) (S.L.cockpit_tuertaster3)

{trigger:bus_doorfront0_external}
'   (L.L.elec_busbar_avail)
'   {if}
'      (M.L.trg_bus_doorfront0)
'   {endif}
{end}

{trigger:bus_dooraft}
   (M.L.trg_bus_dooraft)
{end}

{trigger:bus_20h-switch}
   (C.L.cockpit_has_20h_switch)
   {if}
      (M.L.trg_bus_20h-switch)
   {endif}
{end}

{trigger:int_haltewunsch}
   1 (S.L.haltewunsch)
{end}

{trigger:door_haltewunsch}
   1 (S.L.haltewunsch) (S.L.door_haltewunsch_knopfdruck)
{end}

{trigger:door_haltewunsch_off}
   0 (S.L.door_haltewunsch_knopfdruck)
{end}

{trigger:cp_schalter_kinderwagen}
   (L.L.door_handsteuerung) ! (S.L.door_handsteuerung)
   {if}
      0 (S.L.door_kinderwagenwunsch)
      (T.L.ev_kippschalter_ein)
   {else}
      (T.L.ev_kippschalter_aus)
   {endif}
      
{end}

{trigger:door_kinderwagenwunsch}
   (L.L.bremse_halte) (L.L.door_handsteuerung) ! &&
   {if}
      1 (S.L.door_kinderwagenwunsch)
   {endif}
{end}


{macro:Door_Init}
   1000 random 500 / 1 - (C.L.door_acc_var) * (C.L.fdoor_acc) + (S.L.doorAcc_0)
   1000 random 500 / 1 - (C.L.door_acc_var) * (C.L.fdoor_acc) + (S.L.doorAcc_1)
   1000 random 500 / 1 - (C.L.door_acc_var) * (C.L.bdoor_acc) + (S.L.doorAcc_2)
   1000 random 500 / 1 - (C.L.door_acc_var) * (C.L.bdoor_acc) + (S.L.doorAcc_3)

   1000 random 500 / 1 - (C.L.door_maxspeed_var) * (C.L.fdoor_maxspeed) + (S.L.doorMaxSpeed_0_norm)
   1000 random 500 / 1 - (C.L.door_maxspeed_var) * (C.L.fdoor_maxspeed) + (S.L.doorMaxSpeed_1_norm)
   1000 random 500 / 1 - (C.L.door_maxspeed_var) * (C.L.bdoor_maxspeed) + (S.L.doorMaxSpeed_2_norm)
   1000 random 500 / 1 - (C.L.door_maxspeed_var) * (C.L.bdoor_maxspeed) + (S.L.doorMaxSpeed_3_norm)

   (C.L.door_refl) (S.L.doorRefl_0)
   (C.L.door_refl) (S.L.doorRefl_1)
   (C.L.door_refl) (S.L.doorRefl_2)
   (C.L.door_refl) (S.L.doorRefl_3)

   
{end}

{macro:Door_Frame}
   (M.L.Door0_Calc)
   (M.L.Door1_Calc)
   (M.L.DoorAftCalc)
   (M.L.Door2_Calc)
   (M.L.Door3_Calc)


   (L.L.door_0) 0.9 > (S.L.PAX_Entry0_Open)
   (L.L.door_1) 0.9 > (S.L.PAX_Entry1_Open)   
   (L.L.door_2) 0.9 > (L.L.door_3) 0.9 > && (S.L.PAX_Exit0_Open) (S.L.PAX_Exit1_Open)

'   "Dauerfeuer"-Haltewunsch über Kinderwagenschalter (macht genau dasselbe wie der "trigger:int_haltewunsch"):
   (L.L.door_handsteuerung) (L.L.door_haltewunsch_knopfdruck) ||
   {if}
      1 (S.L.haltewunsch)
   {endif}

'   Setzen der Haltestellenbremse erst bei Stillstand des Busses:
'   (L.L.bremse_halte_sw) (L.L.door_20h_sw) ||
'   (L.L.bremse_halte) ! (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) < && &&
'   {if}
'      (L.L.elec_busbar_main)
'      {if}
'         (T.L.ev_haltebremse_an)      
'         1 (S.L.bremse_halte)
'      {endif}
'   {endif}
   (L.L.door_2) 0.2 > (L.L.door_3) 0.9 > && (S.L.PAX_Exit0_Open) (S.L.PAX_Exit1_Open)

'   "Dauerfeuer"-Haltewunsch über Kinderwagenschalter (macht genau dasselbe wie der "trigger:int_haltewunsch"):
   (L.L.door_handsteuerung) (L.L.door_haltewunsch_knopfdruck) ||
   {if}
      1 (S.L.haltewunsch)
   {endif}

'   Setzen der Haltestellenbremse erst bei Stillstand des Busses:
   (L.L.bremse_halte_sw) (L.L.door_20h_sw) ||
   (L.L.bremse_halte) ! (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) < && &&
   {if}
      (L.L.elec_busbar_main)
      {if}
         (T.L.ev_haltebremse_an)      
         1 (S.L.bremse_halte)
      {endif}
   {endif}

'   Anhand dieser Bedingungen kann nun die Automatiktür geöffnet werden:
   (M.L.DoorAft_Open)

'   Türfreigabekriterium

   (L.L.bremse_halte_sw) (L.L.bremse_halte) && (S.L.door_freigabe)

'   Haltewunschlampe:
   (L.L.haltewunsch) (L.L.door_2) 0.2 < (L.L.elec_busbar_main) && &&
   {if}
      1 (S.L.haltewunschlampe)
     
      (L.L.stop_request_played) !
      (L.L.haltewunschlampe) &&
      {if}
         (T.L.stop_request)
         {endif}
      1 (S.L.stop_request_played)

      {else}
      0 (S.L.stop_request_played)
      0 (S.L.haltewunschlampe) (S.L.haltewunsch)
   {endif}

'   Abfall des Kinderwagenwunsch-Relais bei fehlender Stromversorgung:

   (L.L.elec_busbar_main) 0 =
   {if}
      0 (S.L.door_kinderwagenwunsch)
   {endif}

'   Beleuchtung der Einstiege


   (L.L.elec_busbar_main)
   {if}
      (L.L.door_0) 0.1 > (L.L.door_1) 0.1 > || (S.L.door_light_1)
      (L.L.door_2) 0.1 > (L.L.door_3) 0.1 > || (S.L.door_light_2)
   {else}
      0 (S.L.door_light_1) (S.L.door_light_2)
   {endif}

   (L.L.elec_busbar_main)
   {if}
      (L.L.door_light_1) 0.1 > (L.L.door_light_2) 0.1 > || (S.L.doorbang-kacha-2)
   {else}
      0 (S.L.doorbang-kacha-2)
   {endif}


'   Druckabhängige Türgeschwindigkeit
   
   (C.L.door_druckluft)
   {if}
      (L.L.doorMaxSpeed_0_norm) (L.L.bremse_p_Tank04) 100000 - 850000 / (S.L.doorMaxSpeed_0)
      (L.L.doorMaxSpeed_1_norm) (L.L.bremse_p_Tank04) 100000 - 850000 / (S.L.doorMaxSpeed_1)
      (L.L.doorMaxSpeed_2_norm) (L.L.bremse_p_Tank04) 100000 - 850000 / (S.L.doorMaxSpeed_2)
      (L.L.doorMaxSpeed_3_norm) (L.L.bremse_p_Tank04) 100000 - 850000 / (S.L.doorMaxSpeed_3)
   {endif}
'----------------------
'   AI-Ablauf:

(L.L.AI_Scheduled_AtStation) s0
1 =
{if}
'Wenn Türen geöffnet werden sollen:
   (L.L.Velocity) (C.L.Door_Bremse_Halte_MaxKMH) <
   {if}
'Nur, wenn v < maxkmh, sonst warten
'Taster jeweils nur betätigen, falls noch nicht an
      (L.L.doorTarget_23) ! (L.L.haltewunsch) &&
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) ! (L.L.door_AI_timer) 0.3 > &&
      {if}
         (M.L.trg_bus_doorfront0)
      {endif}
      (L.L.doorTarget_1) ! (L.L.door_AI_timer) 0.6 > &&
      {if}
         (M.L.trg_bus_doorfront1)
      {endif}
   {else}
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{else}
l0 -1 =
{if}
'Wenn Türen geschlossen werden sollen:
'Taster jeweils nur betätigen, falls noch nicht aus:
   (L.L.doorTarget_1)
   {if}
      (M.L.trg_bus_doorfront1)
      0 (S.L.door_AI_timer)
   {endif}
   (L.L.doorTarget_0) (L.L.door_AI_timer) 0.3 > &&
   {if}
      (M.L.trg_bus_doorfront0)
   {endif}
'Haltestellenbremse erst wegnehmen, wenn alle Türen zu. Dann auch erst den Bus AI-mäßig freigeben:
   (L.L.door_0) 0.1 <
   (L.L.door_1) 0.1 < &&
   (L.L.door_2) 0.1 < &&
   {if}
      0 (S.L.AI_Scheduled_AtStation)
   {else}
'Sollte eine der Türen auf sein und die Haltestellenbremse aus, dann sofort diese einlegen
      (L.L.doorTarget_23)
      {if}
         (M.L.trg_bus_dooraft)
      {endif}
      (L.L.doorTarget_0) !
      (L.L.doorTarget_1) ! &&
      {if}
         0 (S.L.door_AI_timer)
      {endif}
   {endif}
   (L.L.door_AI_timer) (L.S.Timegap) + (S.L.door_AI_timer)
{endif}
{endif}


{end}




{macro:Door0_Calc}
   (C.L.electric_doors)
   {if}
      (L.L.doorTarget_0)
      {if}
         (L.L.door_0) (F.L.door_0_opn_speed) (S.L.doorMaxSpeed_0)
      {else}
         (L.L.door_0) (F.L.door_0_cls_speed) (S.L.doorMaxSpeed_0)
      {endif}

      (C.L.fdoor_acc) (S.L.doorAcc_0)

      (L.L.doorTarget_0) ! (L.L.doorSpeed_0) s0 abs 0.05 > (L.L.door_0) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_0) <
         {if}
            (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * - (S.L.doorSpeed_0)
         {else}
            (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * + (S.L.doorSpeed_0)
         {endif}
         (L.L.door_0) (L.L.doorSpeed_0) (L.S.Timegap) * + (S.L.door_0)
      {else}
         (L.L.doorSpeed_0) abs 0.05 > (L.L.door_0) 1 < || (L.L.doorTarget_0) &&
         {if}
            l0 (L.L.doorMaxSpeed_0) <
            {if}
               (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * + (S.L.doorSpeed_0)
            {else}
               (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * - (S.L.doorSpeed_0)
            {endif}
            (L.L.door_0) (L.L.doorSpeed_0) (L.S.Timegap) * + (S.L.door_0)
         {else}
            0 (S.L.doorSpeed_0)
         {endif}
      {endif}
   {else}
      (L.L.doorTarget_0) ! (L.L.doorSpeed_0) s0 abs 0.05 > (L.L.door_0) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_0) <
         {if}
            (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * - (S.L.doorSpeed_0)
         {endif}
         (L.L.door_0) (L.L.doorSpeed_0) (L.S.Timegap) * + (S.L.door_0)
      {else}
         (L.L.doorSpeed_0) abs 0.05 > (L.L.door_0) 1 < || (L.L.doorTarget_0) &&
         {if}
            l0 (L.L.doorMaxSpeed_0) <
            {if}
               (L.L.doorSpeed_0) (L.L.doorAcc_0) (L.S.Timegap) * + (S.L.doorSpeed_0)
            {endif}
            (L.L.door_0) (L.L.doorSpeed_0) (L.S.Timegap) * + (S.L.door_0)
         {else}
            0 (S.L.doorSpeed_0)
         {endif}
      {endif}
   {endif}

   (L.L.door_0) 1 >
   {if}
      (T.L.ev_doorhitopen_0)
      1 (S.L.door_0)
      (L.L.doorSpeed_0) /-/ (L.L.doorRefl_0) * (S.L.doorSpeed_0)
   {else}
      (L.L.door_0) 0 <
      {if}
         (T.L.ev_doorhitclose_0)
         0 (S.L.door_0)
         (L.L.doorSpeed_0) /-/ (L.L.doorRefl_0) * (S.L.doorSpeed_0)
      {endif}
   {endif}
{end}

{macro:Door1_Calc}
   (C.L.electric_doors)
   {if}
      (L.L.doorTarget_1)
      {if}
         (L.L.door_1) (F.L.door_1_opn_speed) (S.L.doorMaxSpeed_1)
      {else}
         (L.L.door_1) (F.L.door_1_cls_speed) (S.L.doorMaxSpeed_1)
      {endif}

      (C.L.fdoor_acc) (S.L.doorAcc_1)

      (L.L.doorTarget_1) ! (L.L.doorSpeed_1) s0 abs 0.05 > (L.L.door_1) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_1) <
         {if}
            (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * - (S.L.doorSpeed_1)
         {else}
            (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * + (S.L.doorSpeed_1)
         {endif}
         (L.L.door_1) (L.L.doorSpeed_1) (L.S.Timegap) * + (S.L.door_1)
      {else}
         (L.L.doorSpeed_1) abs 0.05 > (L.L.door_1) 1 < || (L.L.doorTarget_1) &&
         {if}
            l0 (L.L.doorMaxSpeed_1) <
            {if}
               (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * + (S.L.doorSpeed_1)
            {else}
               (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * - (S.L.doorSpeed_1)
            {endif}
            (L.L.door_1) (L.L.doorSpeed_1) (L.S.Timegap) * + (S.L.door_1)
         {else}
            0 (S.L.doorSpeed_1)
         {endif}
      {endif}
   {else}
      (L.L.doorTarget_1) ! (L.L.doorSpeed_1) s0 abs 0.05 > (L.L.door_1) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_1) <
         {if}
            (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * - (S.L.doorSpeed_1)
         {endif}
         (L.L.door_1) (L.L.doorSpeed_1) (L.S.Timegap) * + (S.L.door_1)
      {else}
         (L.L.doorSpeed_1) abs 0.05 > (L.L.door_1) 1 < || (L.L.doorTarget_1) &&
         {if}
            l0 (L.L.doorMaxSpeed_1) <
            {if}
               (L.L.doorSpeed_1) (L.L.doorAcc_1) (L.S.Timegap) * + (S.L.doorSpeed_1)
            {endif}
            (L.L.door_1) (L.L.doorSpeed_1) (L.S.Timegap) * + (S.L.door_1)
         {else}
            0 (S.L.doorSpeed_1)
         {endif}
      {endif}
   {endif}
   (L.L.door_1) 1 >
   {if}
      (T.L.ev_doorhitopen_1)
      1 (S.L.door_1)
      (L.L.doorSpeed_1) /-/ (L.L.doorRefl_1) * (S.L.doorSpeed_1)
   {else}
      (L.L.door_1) 0 <
      {if}
         (T.L.ev_doorhitclose_1)
         0 (S.L.door_1)
         (L.L.doorSpeed_1) /-/ (L.L.doorRefl_1) * (S.L.doorSpeed_1)
      {endif}
   {endif}
{end}

{macro:DoorAft_Open}

   (L.L.haltewunsch) (L.L.bremse_halte) &&
   {if}
      (L.L.doorTarget_23) !
      (L.L.bremse_halte_sw) &&
      {if}
         (T.L.ev_doortriggeropen_2)
         1 (S.L.doorTarget_23)
         (C.L.door_druckluft)
         {if}
         (L.L.bremse_p_Tank04) 100000 - 0.96 * 100000 + (S.L.bremse_p_Tank04)
         {endif}
      {endif}
      0 (S.L.doorAftLastOpen)      
   {endif}
{end}

{macro:DoorAftCalc}

   (L.L.bremse_halte_sw) !
   (L.L.door_20h_sw) ! &&
   (L.L.door_2) 0 = &&
   (L.L.door_3) 0 = &&
   (L.L.elec_busbar_main) ! ||
   (L.L.bremse_halte) &&
   {if}
      0 (S.L.bremse_halte) (S.L.doorAftLastOpen)
      (T.L.ev_haltebremse_aus)
   {endif}

   (L.L.elec_busbar_main)
   {if}
      (L.L.bremse_halte)
      {if}
         (L.L.doorAftLastOpen) (L.S.Timegap) + (S.L.doorAftLastOpen)
      {endif}

      (L.L.doorTarget_23)
      (L.L.doorAftLastOpen) (C.L.doorAftOpenTime) > &&
      {if}
         (T.L.ev_doortriggerclose_2)
         0 (S.L.doorTarget_23)
         (C.L.door_druckluft)
         {if}
         (L.L.bremse_p_Tank04) 100000 - 0.96 * 100000 + (S.L.bremse_p_Tank04)
         {endif}
      {endif}
   {endif}
{end}

{macro:Door2_Calc}
   (C.L.electric_doors)
   {if}
      (L.L.doorTarget_23)
      {if}
         (L.L.door_2) (F.L.door_2_opn_speed) (S.L.doorMaxSpeed_2)
      {else}
         (L.L.door_2) (F.L.door_2_cls_speed) (S.L.doorMaxSpeed_2)
      {endif}

      (C.L.bdoor_acc) (S.L.doorAcc_2)

      (L.L.doorTarget_23) ! (L.L.doorSpeed_2) s0 abs 0.05 > (L.L.door_2) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_2) <
         {if}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
         {else}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
         {endif}
         (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
      {else}
         (L.L.doorSpeed_2) abs 0.05 > (L.L.door_2) 1 < || (L.L.doorTarget_23) &&
         {if}
            l0 (L.L.doorMaxSpeed_2) <
            {if}
               (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
            {else}
               (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
            {endif}
            (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
         {else}
            0 (S.L.doorSpeed_2)
         {endif}
      {endif}
   {else}
      (L.L.doorTarget_23) ! (L.L.doorSpeed_2) s0 abs 0.05 > (L.L.door_2) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_2) <
         {if}
            (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * - (S.L.doorSpeed_2)
         {endif}
         (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
      {else}
         (L.L.doorSpeed_2) abs 0.05 > (L.L.door_2) 1 < || (L.L.doorTarget_23) &&
         {if}
            l0 (L.L.doorMaxSpeed_2) <
            {if}
               (L.L.doorSpeed_2) (L.L.doorAcc_2) (L.S.Timegap) * + (S.L.doorSpeed_2)
            {endif}
            (L.L.door_2) (L.L.doorSpeed_2) (L.S.Timegap) * + (S.L.door_2)
         {else}
            0 (S.L.doorSpeed_2)
         {endif}
      {endif}
   {endif}

   (L.L.door_2) 1 >
   {if}
      (T.L.ev_doorhitopen_2)
      1 (S.L.door_2)
      (L.L.doorSpeed_2) /-/ (L.L.doorRefl_2) * (S.L.doorSpeed_2)
   {else}
      (L.L.door_2) 0 <
      {if}
         (T.L.ev_doorhitclose_2)
         0 (S.L.door_2)
         (L.L.doorSpeed_2) /-/ (L.L.doorRefl_2) * (S.L.doorSpeed_2)
      {endif}
   {endif}
{end}

{macro:Door3_Calc}
   (C.L.electric_doors)
   {if}
      (L.L.doorTarget_23)
      {if}
         (L.L.door_3) (F.L.door_3_opn_speed) (S.L.doorMaxSpeed_3)
      {else}
         (L.L.door_3) (F.L.door_3_cls_speed) (S.L.doorMaxSpeed_3)
      {endif}

      (C.L.bdoor_acc) (S.L.doorAcc_3)

      (L.L.doorTarget_23) ! (L.L.doorSpeed_3) s0 abs 0.05 > (L.L.door_3) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_3) <
         {if}
            (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * - (S.L.doorSpeed_3)
         {else}
            (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * + (S.L.doorSpeed_3)
         {endif}
         (L.L.door_3) (L.L.doorSpeed_3) (L.S.Timegap) * + (S.L.door_3)
      {else}
         (L.L.doorSpeed_3) abs 0.05 > (L.L.door_3) 1 < || (L.L.doorTarget_23) &&
         {if}
            l0 (L.L.doorMaxSpeed_3) <
            {if}
               (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * + (S.L.doorSpeed_3)
            {else}
               (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * - (S.L.doorSpeed_3)
            {endif}
            (L.L.door_3) (L.L.doorSpeed_3) (L.S.Timegap) * + (S.L.door_3)
         {else}
            0 (S.L.doorSpeed_3)
         {endif}
      {endif}
   {else}
      (L.L.doorTarget_23) ! (L.L.doorSpeed_3) s0 abs 0.05 > (L.L.door_3) 0 > || &&
      {if}
         l0 /-/ (L.L.doorMaxSpeed_3) <
         {if}
            (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * - (S.L.doorSpeed_3)
         {endif}
         (L.L.door_3) (L.L.doorSpeed_3) (L.S.Timegap) * + (S.L.door_3)
      {else}
         (L.L.doorSpeed_3) abs 0.05 > (L.L.door_3) 1 < || (L.L.doorTarget_23) &&
         {if}
            l0 (L.L.doorMaxSpeed_3) <
            {if}
               (L.L.doorSpeed_3) (L.L.doorAcc_3) (L.S.Timegap) * + (S.L.doorSpeed_3)
            {endif}
            (L.L.door_3) (L.L.doorSpeed_3) (L.S.Timegap) * + (S.L.door_3)
         {else}
            0 (S.L.doorSpeed_3)
         {endif}
      {endif}
   {endif}

   (L.L.door_3) 1 >
   {if}
      (T.L.ev_doorhitopen_3)
      1 (S.L.door_3)
      (L.L.doorSpeed_3) /-/ (L.L.doorRefl_3) * (S.L.doorSpeed_3)
   {else}
      (L.L.door_3) 0 <
      {if}
         (T.L.ev_doorhitclose_3)
         0 (S.L.door_3)
         (L.L.doorSpeed_3) /-/ (L.L.doorRefl_3) * (S.L.doorSpeed_3)
      {endif}
   {endif}

{end}

{macro:trg_bus_doorfront0}

   (L.L.doorTarget_0) ! (S.L.doorTarget_0)
   {if}
      (T.L.ev_doortriggeropen_0)
   {else}
      (T.L.ev_doortriggerclose_0)
   {endif}
      (C.L.door_druckluft)
      {if}
      (L.L.bremse_p_Tank04) 100000 - 0.98 * 100000 + (S.L.bremse_p_Tank04)
      {endif}
{end}

{macro:trg_bus_doorfront1}

   (L.L.doorTarget_1) ! (S.L.doorTarget_1)
   {if}
      (T.L.ev_doortriggeropen_1)
   {else}
      (T.L.ev_doortriggerclose_1)
   {endif}   
      (C.L.door_druckluft)
      {if}
      (L.L.bremse_p_Tank04) 100000 - 0.98 * 100000 + (S.L.bremse_p_Tank04)
      {endif}
{end}

{macro:trg_front_door_all_close}
   1 (S.L.cockpit_tuertaster3)
   (L.L.doorTarget_1)
   (L.L.doorTarget_0) ||
   {if}
      0 (S.L.doorTarget_0) (S.L.doorTarget_1)
      (T.L.ev_doortriggerclose_0)
   {endif}
    (C.L.door_druckluft)
    {if}
      (L.L.bremse_p_Tank04) 100000 - 0.98 * 100000 + (S.L.bremse_p_Tank04)
    {endif}
{end}


{macro:trg_bus_dooraft}
   (L.L.doorTarget_23) ! (S.L.doorTarget_23)
        {if}
                (T.L.ev_doortriggeropen_2)
        {else}
                (T.L.ev_doortriggerclose_2)
        {endif}       
                (C.L.door_druckluft)
                {if}
                (L.L.bremse_p_Tank04) 100000 - 0.98 * 100000 + (S.L.bremse_p_Tank04)
                {endif}
{end}

{macro:trg_bus_20h-switch}
   (L.L.door_20h_sw) ! (S.L.door_20h_sw)
   
   (L.L.door_20h_sw)
   {if}
      (T.L.ev_haltebremse_sw_an)
   {else}
      (T.L.ev_haltebremse_sw_aus)
   {endif}   
{end}